vos/corelibs/vos/parsemessage_lexer.ll

Go to the documentation of this file.

/*
    This file is part of the Virtual Object System of
    the Interreality project.

    Copyright (C) 2003 Peter Amstutz

    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Lesser General Public
    License as published by the Free Software Foundation; either
    version 2 of the License, or (at your option) any later version.

    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Lesser General Public License for more details.

    You should have received a copy of the GNU Lesser General Public
    License along with this library; if not, write to the Free Software
    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307  USA

    Peter Amstutz <amstutz@cs.umass.edu>
*/
%{
#include <stdio.h>
#include "parsemessage_parser.h"
#include "msglexer.hh"
#include "message.hh"
#include "messageblock.hh"

using namespace VOS;

#define READQUOTED {                                         \
    if(parsestate->read_quoted) {                            \
        int ret;                                             \
        pREF(Message*, m, parsestate->m->lastMessage(),      \
            (m->fields.back()).quoted = true;                \
            std::string& target = (m->fields.back()).source; \
            target.resize(parsestate->read_quoted);          \
            int i;                                           \
            for(i = 0; i < yyleng; i++) {                    \
                target[i] = yytext[i];                       \
            }                                                \
            for(; i < parsestate->read_quoted; i++) {        \
                int c;                                       \
                if((c = yyinput()) == EOF) break;            \
                target[i] = c;                               \
            }                                                \
            parsestate->chars_read += i;                     \
            if(i != parsestate->read_quoted) ret = EOF;      \
            else ret = CDATA;                                \
        );                                                   \
        return ret;                                          \
    }                                                        \
}


%}
/*
#define cin std::cin
#define cout std::cout
#define istream std::istream
#define ostream std::ostream
*/

%option c++
%option noyywrap
%option yyclass="msgFlexLexer"
%x S_TAG
%x S_ATTRIBUTES
%x S_EQ
%x S_QUOTE
%x S_QUOTESTR
%x S_TAGEND
%%
<INITIAL>[^<]+ { READQUOTED; return CDATA; }
<INITIAL>\<!--([^-]|--[^>])*--\> { READQUOTED; return COMMENT; }
<INITIAL>\< { READQUOTED; BEGIN(S_TAG); return yytext[0]; }
<S_TAG>\/ { return yytext[0]; }
<S_TAG>messageblock { BEGIN(S_ATTRIBUTES); return MESSAGEBLOCK; }
<S_TAG>[[:alnum:]][[:alnum:]:_\-]*  { BEGIN(S_ATTRIBUTES); return TAG; }
<S_TAG>. { return 0; }
<S_ATTRIBUTES>[[:alnum:]:]+ { BEGIN(S_EQ); return TAG; }
<S_ATTRIBUTES>[[:space:]]* { return SPACE; }
<S_ATTRIBUTES>\<!--([^-]|--[^>])*--\> { return COMMENT; }
<S_ATTRIBUTES>\/ { BEGIN(S_TAGEND); return yytext[0]; }
<S_ATTRIBUTES>\> { BEGIN(INITIAL); return yytext[0]; }
<S_ATTRIBUTES>. { return 0; }
<S_EQ>= { BEGIN(S_QUOTE); return yytext[0]; }
<S_EQ>. { return 0; }
<S_QUOTE>\" {  BEGIN(S_QUOTESTR); return yytext[0]; }
<S_QUOTE>. { return 0; }
<S_QUOTESTR>[^"]* { return QUOTESTR; }
<S_QUOTESTR>\" { BEGIN(S_ATTRIBUTES); return yytext[0]; }
<S_TAGEND>> { BEGIN(INITIAL); return yytext[0]; }
<S_TAGEND>. { return 0; }
%%

---