vos/corelibs/vos/parsemessage_parser.yy

Go to the documentation of this file.

/*
    This file is part of the Virtual Object System of
    the Interreality project (http://interreality.org).

    Copyright (C) 2001-2003 Peter Amstutz

    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Lesser General Public
    License as published by the Free Software Foundation; either
    version 2 of the License, or (at your option) any later version.

    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Lesser General Public License for more details.

    You should have received a copy of the GNU Lesser General Public
    License along with this library; if not, write to the Free Software
    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307  USA

    Peter Amstutz <amstutz@cs.umass.edu>
*/
/* Parse basic messages in an xml-ish format */
     
%{
#define yyparse VOS::msgparse
#define yylex msglex
#define yyerror msgerror
#define yylval msglval
#define yychar msgchar
#define yydebug msgdebug
#define yynerrs msgnerrs

#define YYSTYPE char*

#include <vos/vosdefs.hh>
#include <vos/parsemessage_parser.h>
#include <vos/messageblock.hh>
#include <vos/message.hh>

#define YYERROR_VERBOSE
#define YYPARSE_PARAM extra
#define YYLEX_PARAM extra

#undef __GNUC_MINOR__
%}

%token TAG
%token SPACE
%token QUOTESTR
%token CDATA
%token MESSAGEBLOCK
%token COMMENT
%pure_parser
%% /* Grammar rules and actions follow */

start: cspace messageblock  { ((parse_state_t*)extra)->done=1; }
     | cspace message { ((parse_state_t*)extra)->done=1; }
;

messageblock: '<' MESSAGEBLOCK aspace options ospace '>' cspace messages cspace '<' '/' MESSAGEBLOCK '>'
            | '<' MESSAGEBLOCK aspace options ospace '>' cspace '<' '/' MESSAGEBLOCK '>'
            | '<' MESSAGEBLOCK '>' cspace messages cspace '<' '/' MESSAGEBLOCK '>'
;

options: option
     | options aspace option
;

option: TAG '=' '"' QUOTESTR '"' {
    string astr($1);
    if(astr == "name") {
        ((parse_state_t*)extra)->m->setName($4);
    } else if(astr == "length") {
        ((parse_state_t*)extra)->expected_length = abs(atoi($4));
    }
    free($1);
    free($4);
}
;

messages: message
        | messages cspace message
;

message: begintag cspace params cspace endtag
       | begintag cspace endtag
       | begintagonly
;

tagstart: '<' TAG {
    pREF(VOS::Message*, m, new VOS::Message(),
        ((parse_state_t*)extra)->m->insertMessage(-1, m);
        m->setType($2);
    );
    free($2);   
};

begintag: tagstart aspace attributes ospace '>'
;

begintagonly: tagstart aspace attributes ospace '/' '>'
;

endtag:  '<' '/' TAG '>' {
    free($3);
}
;

attributes: attr
     | attributes aspace attr
;

attr: TAG '=' '"' QUOTESTR '"' {
    string astr($1);
    if(astr == "to") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setTo($4));
    } else if(astr == "from") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setFrom($4));
    } else if(astr == "method") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setMethod($4));
    } else if(astr == "nonce") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setNonce($4));
    } else if(astr == "length") {
         if(((parse_state_t*)extra)->expected_length == 0) 
            ((parse_state_t*)extra)->expected_length = abs(atoi($4));
    } else if(astr == "time") {
        float x;
        sscanf($4, "%f", &x);
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setTime(x));
    } else if(astr == "depends") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->setDependency($4));
    }
    free($1);
    free($4);
}
;

aspace: SPACE | COMMENT aspace | SPACE aspace;

ospace: | COMMENT ospace | SPACE ospace
;

cspace: | COMMENT cspace | CDATA cspace {
    free($1);
};

params: param
     | params cspace param
;

param: '<' TAG '>' CDATA '<' '/' TAG '>' { 
    if(strcmp($2, $7)==0) {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->insertField(-1, $2, $4));
    }
    free($2);
    free($4);
    free($7);
} | beginquotedparam quotedcdata endquotedparam
  | '<' TAG '>' '<' '/' TAG '>' { 
    free($2);
    free($6);
    if(strcmp($2, $6)==0) {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->insertField(-1, $2, ""));
    }
} | '<' TAG ospace '/' '>' {
    pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), m->insertField(-1, $2, ""));
    free($2);
}
;

beginquotedparam: '<' TAG aspace TAG '=' '"' QUOTESTR '"' ospace '>' {
    string astr($4);
/*  cout << "in beginquotedparm!!!\n"; */
    if(astr == "length") {
        pREF(VOS::Message*, m, ((parse_state_t*)extra)->m->lastMessage(), 
            m->insertField(-1, $2, "");
            ((parse_state_t*)extra)->read_quoted = abs(atoi($7));
        );
    }
    free($2);
    free($4);
    free($7);
}
;

quotedcdata: CDATA {
    ((parse_state_t*)extra)->read_quoted = 0;
}
;

endquotedparam: '<' '/' TAG '>' 
;

---