vos/corelibs/typechain/tclexer.ll

Go to the documentation of this file.

/** tclexer Typechain Flex Lexical Scanner
    @see TypechainLexer


    @author Reed Hedges <reed@zerohour.net>

    Copyright (C) 2002 Reed Hedges

    This library is free software; you can redistribute it and/or
    modify it under the terms of the GNU Lesser General Public
    License as published by the Free Software Foundation; either
    version 2 of the License, or (at your option) any later version.

    This library is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
    Lesser General Public License for more details.

    You should have received a copy of the GNU Lesser General Public
    License along with this library; if not, write to the Free Software
    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307  USA

*/

%option c++
%option noyywrap
%option yyclass="TypechainLexer"
    //%option outfile="tclexer.cc"
%option prefix="tc"

    // Don't use this for testing (See below) !! :
%option never-interactive


%{

//#define TESTING 1 // If defined, a test program is generated (with main()).

#include "tclexer.hh"
#include <iostream>

//#define YY_USER_ACTION    printf("matched: %s.\n", yytext);
    

%}

%x PARAMKEY PARAMVAL

WS  [ \t\r\n]
TOK [^;|\: \t\r\n(),=]+


%%

{WS}*[;|\:]{WS}*                  complete_token(token, params);  clear_vars();
{TOK}                             token = string(yytext);
{WS}*"("{WS}*                     BEGIN(PARAMKEY);
<PARAMKEY>{TOK}                   params[yytext] = ""; lastkey = strdup(yytext);
<PARAMVAL>{TOK}                   params[lastkey] = string(yytext);
<PARAMKEY>{WS}*"="{WS}*           BEGIN(PARAMVAL);
<PARAMKEY,PARAMVAL>{WS}*","{WS}*  BEGIN(PARAMKEY);
<PARAMKEY,PARAMVAL>{WS}*")"{WS}*  BEGIN(INITIAL);
<<EOF>>                           final_type(token, params); clear_vars(); return 0;

%%


#ifdef TESTING
/* Testing: */

class TestingTypechainLexer : public TypechainLexer {

public:
    TestingTypechainLexer(string s) : TypechainLexer(s) {
    }

    void print_params(map<string,string> params) {
        for(map<string,string>::const_iterator i = params.begin(); i != params.end(); i++) {
            printf("\tkey: '%s'  val: '%s'\n", i->first.c_str(), i->second.c_str());
        }
    }

    void complete_token(string token, map<string, string> params) {
        printf("complete_token: '%s'. params:\n", token.c_str());
        print_params(params);
    }

    void final_type(string token, map<string, string> params) {
        printf("final_type: '%s'. params:\n", token.c_str());
        print_params(params);
    }


};


int main() {
    TestingTypechainLexer lexer("hello; \n world(foo= bar\t, baz  ) |      la/la");
    lexer.yylex();
    return 0;
}

#endif //ifdef TESTING

---